Innhald

# Matematiske funksjonar

Dette avsnittet indeheld dei matematiske funksjonane i Calc. For å opna Funksjonsvegvisaren, vel Set inn → Funksjon.

## SAMANDRAG

Denne funksjonen returnerer eit samandrag (aggregate) av utrekningane i området. Du kan bruka ulike samandragsfunksjonar lista nedanfor. Samandragsfunksjonen gjev deg høve til å sløyfa gøymde rader, feil, DELSUM og andre funksjonsresultat i SAMANDRAG i utrekningane.

## RÅSUBTRAKSJON

Subtraherer tal og gjev svaret utan å bry seg om små avrundingsfeil.

## SUMMER

Adderer eit talsett.

## SUMMER.VISS

Avgjer kva verdiar i eit celleområde som oppfyller eit spesifisert kriterium, og returnerer deretter summen av samsvarande verdiar. Alternativt kan funksjonen finna ut kva verdiar i eit celleområde som oppfyller eit kriterium, og deretter returnera summen av verdiar i dei tilsvarande cellene i eit anna celleområde. Norsk nynorsk

## FARGE

Returnerer ein talverdi som er rekna ut på grunnlag av dei tre fargane (raud, grøn og blå) og alfakanalen i RGBA-systemet. Resultatet er avhengig av kva fargesystem som er brukt i datamaskinen.

## SUMMER.VISS.SETT (SUMIFS på engelsk)

Returnerer summen av celleverdiane i eit område som oppfyller fleire kriteria i fleire område.

## ABS (ABS på engelsk)

Returnerer absoluttverdien av eit tal.

#### Syntaks

ABS(Tal)

Tal er det talet som den absolutte verdien skal reknast ut for. Den absolutte verdien for eit tal er verdien utan +/- framføre.

#### Eksempel

=ABS(-56) returnerer 56.

=ABS(12) returnerer 12.

=ABS(0) returnerer 0.

## ACOS (ACOS på engelsk)

returnerer invers trigonometrisk cosinus til eit tal.

#### Syntaks

ACOS(Tal)

Denne funksjonen returnerer den inverse trigonometriske cosinus av Tal, det vil seia den vinkelen (i radianar) som har cosinus er Tal. Den returnerte vinkelen er mellom 0 og pi.

For å returnera vinkelen i grader, bruk GRADER-funksjonen.

#### Eksempel

=ACOS(-1) returnerer 3,14159265358979 (pi radianar).

=GRADER((ACOS(0,5)) returnerer 60. Cosinus av 60 grader er 0,5.

## ACOT (ACOT på engelsk)

Returnerer invers kotangens til eit gjeve tal.

#### Syntaks

ACOT(tal)

Denne funksjonen returnerer den inverse trigonometriske cotangens av Tal, det vil seia den vinkelen (i radianar) som har cotangens Tal. Den returnerte vinkelen er mellom 0 og pi.

For å returnera vinkelen i grader, bruk GRADER-funksjonen.

#### Eksempel

=ARCCOT(1) returnerer 0,785398163397448 (pi/4 radianar).

=GRADER(ARCCOT(1 )) returnerer 45. Tangens av 45 grader er 1.

## ACOTH (ACOTH på engelsk)

Returnerer invers hyperbolsk kotangens til eit gjeve tal.

#### Syntaks

ACOTH(tal)

Denne funksjonen returnerer den inverse hyperbolske cotangens av Tal, det vil seia det talet som har hyperbolsk cotangens Tal.

Dersom Tal er mellom -1 og 1 resulterer dette i ein feil.

#### Eksempel

=ARCCOTH(1,1) returnerer den inverse hyperbolske cotangens av 1,1, som er tilnærma lik 1,52226.

## ARCTAN2 (ATAN2 på engelsk)

Returnerer vinkelen (i radianar) mellom x-aksen og ei linje frå utgangspunktet til dette punktet (TalX|TalY).

Denne funksjonen høyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)

#### Syntaks

ARCTAN2(TalX; TalY)

TalX er verdien av x-koordinaten.

TalY er verdien av y-koordinaten

Programmeringsspråk har normalt argumenta i motsett rekkjefølgje i arctan2()-funksjonen.

ARCTAN2 returnerer vinkelen (i radianar) mellom x-aksen og ei linje frå utgangspunktet til dette punktet (TalX|TalY).

#### Eksempel

ARCTAN2(-5;9) returnerer 2,07789 radianar.

Bruk GRADER-funksjonen på resultatet for å få vinkelen i grader.

=GRADER(ARCTAN2(12.3;12.3)) returnerer 45. Tangenten til 45 grader er 1.

LibreOffice gjev tilbake 0 for ARCTAN2(0;0).

Funksjonen kan brukast til å konvertera kartesiske koordinat til polare koordinat.

=GRADER(ARCTAN2(-8;5)) returnerer φ = 147,9 grader

## ARCTANH (ATANH på engelsk)

Returnerer invers hyperbolsk tangens av eit tal.

#### Syntaks

ARCTANH(Tal)

Denne funksjonen returnerer den inverse hyperbolske tangens av Tal, det vil seia den verdien der den hyperbolske tangens er Tal.

Tal må oppfyll vilkåra -1 < Tal < 1.

#### Eksempel

=ARCTANH(0) returnerer 0.

## ASIN (ASIN på engelsk)

Returnerer invers trigonometrisk sinus til eit tal.

#### Syntaks

ASIN(Tal)

Denne funksjonen returnerer den inverse trigonometriske sinus av Tal, det vil seia den vinkelen (i radianar) der sinus er Tal. Den returnerte vinkelen er mellom -pi/2 og +pi/2.

For å returnera vinkelen i grader, bruk GRADER-funksjonen.

#### Eksempel

=ASIN(0) returnerer 0.

ASIN(1) returnerer 1,5707963267949 (pi/2 radianar).

GRADER(ASIN(0,5)) returnerer 30. Sinus av 30 grader er 0,5.

## ASINH (ASINH på engelsk)

Returnerer invers hyperbolsk sinus til eit tal.

#### Syntaks

ASINH(tal)

Denne funksjonen returnerer den inverse hyperbolske sinus av Tal, det vil seia det talet som den inverse hyperbolske sinus er Tal for.

#### Eksempel

=ASINH(-90) returnerer ca. -5,1929877.

=ASINH(SINH(4)) returnerer 4.

## ATAN (ATAN på engelsk)

Returnerer invers trigonometrisk tangens av eit tal.

#### Syntaks

ATAN(Tal)

Denne funksjonen returnerer den inverse trigonometriske tangens av Tal, altså den vinkelen (i radianar) som har tangens Tal. Den returnerte vinkel er mellom -pi/2 og pi/2.

For å returnera vinkelen i grader, bruk GRADER-funksjonen.

#### Eksempel

=ARCTAN(1) returnerer 0,785398163397448 (PI/4 radianar).

=GRADER(ARCTAN(1)) returnerer 45. Tangens av 45 grader er 1.

## AVKORT (TRUNC på engelsk)

Avkortar eit tal, men beheld det gjevne talet på desimalar.

## AVRUND.NED /ROUNDDOWN på engelsk)

Avkortar eit tal, men beheld det gjevne talet på desimalar.

## AVRUND.OPP (ROUNDUP på engelsk)

Rundar eit tal opp, dvs. bort frå null, ut frå ein bestemt presisjon.

#### Syntaks

AVRUND.OPP(Tal[; Desimalar])

Returnerer Tal runda opp (bort frå null) med Desimalar desimalar. Viss Desimalar vert sløyfa eller er null, vil funksjonen runda opp til eit heiltal. Viss Desimalar er negativ, vil funksjonen runda opp til neste 10, 100, 1000 osv.

Denne funksjonen rundar bort frå null. Sjå AVRUND.NED og AVRUND for alternativ.

#### Eksempel

=AVRUND.OPP(1,1111;2) returnerer 1,12.

=AVRUND.OPP(1,2345;1) returnerer 1,3.

=AVRUND.OPP(45,67;0) returnerer 46.

=AVRUND.OPP(-45,67) returnerer -46

=AVRUND.OPP(987,65;-2) returnerer 1000.

## AVRUND (ROUND på engelsk)

Rundar av eit tal til eit oppgjeve tal på desimalar.

#### Syntaks

AVRUND(Tal [; Desimalar])

Returnerer Tal avrunda til Desimalar desimalar. Viss «Desimalar» vert sløyfa eller er null, vil funksjonen avrunda til det næraste heiltalet. Viss Desimalar er negativ, vil funksjonen avrunda til næraste 10, 100, 1000 osv.

Denne funksjonen runda av til det næraste talet. Sjå AVRUND.NED og AVRUND.OPP for alternativ.

#### Eksempel

=AVRUND(2,348;2) returnerer 2,35

=AVRUND(-32,4834; 3) returnerer -32,483. Byt celleformatet for å sjå alle desimalane.

=AVRUND(2,348;0) returnerer 2.

=AVRUND(2,5) returnerer 3.

=AVRUND(987,65;-2) returnerer 1000.

## AVRUND.TIL.ODDETAL (ODD på engelsk)

Runder eit positivt tal opp til næraste heile oddetal og eit negativt tal ned til næraste heile oddetal.

#### Syntaks

AVRUND.TIL.ODDETAL(Tal)

Returnerer Tal runda opp til neste heile oddetal, bort frå null.

#### Eksempel

=AVRUND.TIL.ODDETAL(1,2) returnerer 3.

=AVRUND.TIL.ODDETAL(1) returnerer 1.

=AVRUND.TIL.ODDETAL(0) returnerer 1.

=AVRUND.TIL.ODDETAL(-3,1) returnerer -5.

## AVRUND.TIL.PARTAL (EVEN på engelsk)

Runder eit positivt tal opp til næraste heile partal og eit negativt tal ned til næraste partal.

#### Syntaks

AVRUND.TIL.PARTAL(Tal)

Returnerer Tal runda opp til det næraste partalet, bort frå null.

#### Eksempel

=AVRUND.TIL.PARTAL(2,3) returnerer 4.

=AVRUND.TIL.PARTAL(2) returnerer 2.

=AVRUND.TIL.PARTAL(0) returnerer 0.

=AVRUND.TIL.PARTAL(-0,5) returnerer -2

## COS (COS på engelsk)

Returnerer cosinus av den gjevne vinkelen (i radianar).

#### Syntaks

COS(Tal)

Returnerer (den trigonometriske) sinusen av Tal, vinkelen i radianar.

For å returnera sinusen av ein vinkel i grader kan du bruka funksjonen RADIANAR.

#### Eksempel

COS(PI()*2) returnerer 1, cosinus av 2 * PI radianar.

COS(RADIANAR(60)) returnerer 0,5, som er cosinus av 60 grader.

## COSEKANT (CSC på engelsk)

Returnerer cosekanten av ein gjeven vinkel (i radianar). Cosekanten av ein vinkel er lik 1 dividert med sinus av vinkelen.

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 3.5.

#### Syntaks

COSEKANT (tal)

Returnerer (den trigonometriske) sinusen av Tal, vinkelen i radianar.

For å returnera cosekanten av ein vinkel i grader kan du bruka funksjonen RADIANAR

#### Eksempel

=CSC(PI()/4) returnerer omlag 1,4142135624, som er den inverse av sinus av PI/4 radianar.

=COSEKANT(RADIANAR(30)) returnerer 2, som er cosekanten av 30 grader.

## COSH (COSH på engelsk)

Returnerer hyperbolsk cosinus til eit tal.

#### Syntaks

COSH(tal)

Returnerer den hyperbolske cosinus av Tal.

#### Eksempel

COSH(0) returnerer 1, den hyperbolske cosinus av 0.

## COT (COT på engelsk)

Returnerer cotangens til den gjevne vinkelen (i radianar).

#### Syntaks

COT(tal)

Returnerer (den trigonometriske) cotangens av Tal, vinkelen i radianar.

For å returnera cotangens av ein vinkel i grader, bruk RADIANAR-funksjonen.

Cotangens av ein vinkel svarar til 1 dividert med tangens til vinkelen.

### Eksempel:

COT(PI()/4) returnerer 1, cotangens av pi/4 radianar.

=COT(RADIANAR(45)) returnerer 1, cotangens av 45 grader.

## COTH (COTH på engelsk)

Returnerer invers hyperbolsk cotangens til eit gjeve tal (vinkel).

#### Syntaks

COTH(tal)

Returnerer den hyperbolske cotangens av Tal.

#### Eksempel

=COTH(1) returnerer den hyperbolske cotangens av 1, ca. 1,3130.

## DELSUM (SUBTOTAL på engelsk)

Rekn ut delsummar. Dersom eit dataområde alt inneheld delsum(mar) vert ikkje desse brukte til vidare utrekningar. Om du brukar denne funksjonen saman med automatiserte filter vert berre dei filtrerte postane tekne med.

#### Syntaks

DELSUM(Funksjon; Område)

Funksjon er eit tal som står for ein av desse funksjonane:

Funksjonsindeks (tek med gøymde verdiar) | Funksjonsindeks (ignorer gøymde verdiar) | Funksjon
--- | --- | ---
1 | 101 | GJENNOMSNITT (AVERAGE på engelsk)
2 | 102 | TAL.PÅ (COUNT på engelsk)
3 | 103 | TAL.PÅA (COUNTA på engelsk)
4 | 104 | MAKS (MAX på engelsk)
5 | 105 | MIN
6 | 106 | PRODUKT (PRODUCT på engelsk)
7 | 107 | STDAV (STDEV på engelsk)
8 | 108 | STDAVP (STDEVP på engelsk)
9 | 109 | SUM
10 | 110 | VARIANS (VAR på engelsk)
11 | 111 | VARIANSP (VARP på engelsk)

Bruk tala 1 - 11 for å ta med manuelt gøymde rader eller 101 - 111 for å ikkje ta dei med. Celler som er filtrerte ut vert aldri rekna med.

Område er området der cellene er tekne med.

Denne funksjonen ignorerer all tekst og tomme celle innføre eit dataområde. Har du mistanke om feil resultat frå denne funksjonen, ser du etter tekst i dataområda. For å utheva tekstinnhald i dataområdet, brukar du funksjonen verdimerking.

#### Eksempel

Du har ein tabell i celleområde A1:B6 som inneheld ei deleliste for 10 studentar.

| A | B
--- | --- | ---
1 | VARE | MENGD
2 | Penn | 10
3 | Blyant | 10
4 | Notisblokk | 10
5 | Viskeler | 10
6 | Blyantspissar | 10

Lat oss seia at ei rad er manuelt gøymd, så viser den første formelen summen av dei 5 figurane som vart filtrert. Den andre berre summen av dei 4 synlege tala.

=DELSUM(9;B2:B5) returnerer 50.

=DELSUM((109;B2:B6) returnerer 40.

## EKSP (EXP på engelsk)

Returnerer e opphøgd i eit tal. Konstanten e har den omtrentlege verdien 2,71828182845904.

#### Syntaks

EKSP(Tal)

Tal er potensen som e skal opphøgjast til.

#### Eksempel

=EKSP(1) returnerer 2,71828182845904, den matematiske konstanten e så nøyaktig Calc brukar han.

## EUROKONVERTER (EUROCONVERT på engelsk)

Konverterer mellom gammal europeisk nasjonal valuta og til og frå Euro.

#### Syntaks

EUROKONVERTER(Verdi; "Frå_valuta"; "Til_valuta"[; full_presisjon][; triangulær_presisjon])

Verdi er valutasummen som skal konverterast.

Frå_valuta og til_valuta er dei valutaeiningane som skal konverterast frå eller til. Dei må vera tekst og som den offisielle forkortinga for den relevante valutaeininga (for eksempel "EUR") som vist i tabellen nedanfor. Kursane (vist per Euro) er definerte av Den europeiske kommisjonen.

Full_presisjon er valfri. Viss denne vert sløyfa eller er USANN, vert resultatet avrunda med like mange desimalar som i «Til valuta«. Viss Full_presisjon er SANN vert resultatet ikkje avrunda.

Triangulær_presisjon er valfritt. Viss triangulær_presisjon er gjeve og >=3, vert mellomresultatet for den triangulære konverteringa (valuta1, EUR, valuta2) avrunda til denne presisjonen. Viss triangulær_presisjon ikkje er gjeven, vert mellomresultatet ikkje avrunda. Viss Til-valuta er «EUR», så vert triangulær_presisjon brukt som om triangulering var nødvendig og konvertering frå EUR til EUR vart brukt.

### Eksempel

=EUROKONVERTER(100;"NOK";"EUR") konverterer 100 norske kroner til Euro.

=EUROKONVERTER(100;"EUR";"NOK") konverterer 100 Euro til norske kroner.

## FAKULTET (FACT på engelsk)

Returnerer fakultetet til eit ikkje-negativt heiltal.

#### Syntaks

FAKULTET(Heiltal)

Returnerer Heiltal!, fakultets-verdien av Heiltal, berekna som 1*2*3*4* … * Heiltal.

Returnerer feilen «ugyldig argument» viss argumentet er eit negativt heiltal.

Returnerer feilen #VERDI! viss argumentet er større enn 170, noko som resulterer i eit for stort heiltal (omtrent 7E+306).

=FAKULTET(0) returnerer 1 per definisjon.

Viss argumentet er eit tal som ikkje er eit heiltal, vert det runda ned til heiltalsverdien.

#### Eksempel

=FAKULTET(3) returnerer 6.

=FAKULTET(3,8) returnerer 6.

=FAKULTET(0) returnerer 1.

## FORTEIKN (SIGN på engelsk)

Returnerer forteiknet av eit tal. Returnerer 1 viss talet er positivt, -1 viss det er negativt og 0 viss det er null.

#### Syntaks

FORTEIKN(tal)

Tal er talet som forteiknet skal finnast for.

#### Eksempel

=FORTEIKN(3,4) returnerer 1

=FORTEIKN(-4,5) returnerer -1

## GRADER (DEGREES på engelsk)

Gjer om radianar til grader.

#### Syntaks

GRADER(Tal)

Tal er vinklen i radianar som skal konverterast til grader.

#### Eksempel

=GRADER(PI()) returnerer 180 grader.

## HEILTAL (INT på engelsk)

Rundar av eit tal ned til næraste heiltal.

#### Syntaks

HEILTAL(tal)

Returnerer Tal runda ned til næraste heiltal.

Negative tal vert runda ned til heiltalet under.

#### Eksempel

=HEILTAL(5,7) returnerer 5.

=HEILTAL(-1,3) returnerer -2.

## HYPERBOLSK.COSEKANT (CSCH på engelsk)

Returnerer hyperbolsk cosekant til eit tal.

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 3.5.

#### Syntaks

HYPERBOLSK.COSEKANT(Tal)

Returnerer den hyperbolske cosinus av Tal.

#### Eksempel

=CSCH(1) returnerer ca. 0.8509181282, den hyperbolske cosekans av 1.

## HYPERBOLSK.SEKANT

Returnerer invers hyperbolsk cosinus til eit tal.

#### Syntaks

HYPERBOLSK.SEKANT(Tal)

Denne funksjonen returnerer den inverse hyperbolske cosinus av Tal, det vil seia det talet som har den hyperbolske cosinus «Tal».

Talet må vera større enn eller lik 1.

#### Eksempel

=ACOSH(1) returnerer 0.

=ACOSH(COSH(4)) returnerer 4.

## HYPERBOLSK.SEKANT (SECH på engelsk)

Returnerer hyperbolsk sekans til eit tal.

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 3.5.

#### Syntaks

SEKUND(Tal)

Returnerer den hyperbolske sekans av Tal.

#### Eksempel

=SECH(0) returnerer 1, den hyperbolske sekanten av 0.

## KOMBINASJONA (COMBINA på engelsk)

Returnerer talet på kombinasjonar for ei delmengd av element, også gjentakingar.

#### Syntaks

KOMBINASJONA(Talpå1; Talpå2)

Talpå1 er talet på element som skal veljast frå mengda.

Talpå2 er talet på element som skal veljast frå mengda.

KOMBINASJONA returnerer kor mange måtar det er råd å velja desse elementa på når rekkjefølgja ikkje betyr noko og når det same elementet kan brukast fleire gongar. Viss det for eksempel er tre element , A, B og C, i ei mengde, kan du velja to element på seks ulike måtar: AA, AB, AC, BB, BC og CC.

KOMBINASJONA implementerer formelen: (Talpå1+Talpå2-1)! / (Talpå2! (Talpå1-1)!)

#### Eksempel

=KOMBINASJONA(3;2) returnerer 6.

## KOMBINASJON (COMBIN på engelsk)

Returnerer talet på kombinasjonar av element utan gjentaking.

#### Syntaks

KOMBINASJON(Tal_1; Tal_2)

Talpå1 er talet på element som skal veljast frå mengda.

Talpå2 er talet på element som skal veljast frå mengda.

KOMBINASJON returnerer kor mange ordna måtar desse elementa kan veljast på. Viss det for eksempel er 3 element, A, B og C i ei mengd, kan du velja 2 element på 3 ulike måtar, nemleg AB, AC og BC.

KOMBINASJON implementerer formelen: Talpå1!/(Talpå2!*(Talpå1-Talpå2)!)

#### Eksempel

=KOMBINASJON(3;2) returnerer 3.

## KONVERTER_OOO

Konverterer ein valutaverdi uttrykt i ein av dei eldre valutaane frå eit av dei 19 medlemslanda i eurosonen til Euro eller omvend. Konverteringa brukar dei fastlåste valutakursane som dei gamle valutaane gjekk inn i Euroen med.

Vi rår til å bruka den meir fleksible EUROKONVERTERING-funksjonen for å konvertera mellom desse valutaane. KONVERTER_OOO er ikkje ein standardisert funksjon og kan ikkje flyttast mellom plattformene.

#### Syntaks

KONVERTER_OOO(verdi;"tekst1";"tekst2")

Verdi er valutasummen som skal omreknast.

Tekst1 er ein streng med tre teikn som viser kva valuta det skal konverterast frå.

Tekst2 er ein streng med tre teikn som viser kva valuta det skal konverterast til.

Kvar av Tekst1 og Tekst2 må innehalda ein av desse valutaane: "ATS", "BEF", "CYP", "DEM", "EEK", "ESP", "EUR", "FIM", "FRF", "GRD", "IEP", "ITL", "LTL", "LUF", "LVL", "MTL", "NLG", "PTE", "SIT" eller "SKK".

Éin og berre éin av Tekst1 og Tekst2 må vera lik "EUR".

#### Eksempel

=KONVERTER_OOO(100;"ATS";"EUR") returnerer verdien i euro av 100 Austerikske schilling.

=KONVERTER_OOO(100;"EUR";"DEM") konverterer 100 Euro til tyske mark.

Sjå wikisida CONVERT_OOO for å sjå meir om denne funksjonen (på engelsk).

## KVOTIENT (QUOTIENT på engelsk)

Returnerer heiltalsresultatet av ein divisjon.

#### Syntaks

KVOTIENT(Teljar; Nemnar)

Returnerer heiltalsdelen av Teljar dividert med Nemnar.

KVOTIENT svarar til HEILTAL(teljar/nemnar) når teljar og nemnar har same forteikn, unnateke at funksjonen kan gje ulike feilkodar ved feil. For å vera meir presis, er funksjonen ekvivalent til HEILTAL(teljar/nemnar/FORTEIKN(teljar/nemnar)*FORTEIKN(teljar/nemnar).

#### Eksempel

=KVOTIENT(11; 3) returnerer 3. Resten på 2 vert ikkje teke med.

## KVROT (SQRT på engelsk)

Returnerer den positive kvadratrota av eit tal.

#### Syntaks

KVROT(tal)

Returnerer den positive kvadratrota av Tal.

Tal må vera positivt.

#### Eksempel

=KVROT(16) returnerer 4

=KVROT(-16) returnerer feilmeldinga ugyldig argument.

## LN

Returnerer den naturlege logaritmen til eit tal basert på konstanten e. Verdien av e er tilnærma lik 2,71828182845904.

#### Syntaks

LN(Tal)

Tal er den verdien som den naturlege logaritmen skal reknast ut for.

#### Eksempel

=LN(3) returnerer den naturlege logaritme av 3 (ca. 1,0986).

=LN(EKSP(321)) returnerer 321.

## LOG10 (LOG10 på engelsk)

Returnerer tiarlogaritmen til eit tal.

#### Syntaks

LOG10(Tal)

Returnerer titalslogaritmen av Tal.

#### Eksempel

=LOG10(5) returnerer titalslogaritmen av 5 (cirka 0,69897).

## LOG (LOG på engelsk)

Returnerer logaritmen av eit tal med eit oppgjeve grunntal.

#### Syntaks

LOG(Tal [; Base])

Tal er den verdien som logaritmen skal reknast ut for.

Grunntal er grunntalet for logaritmen. Vis dette er sløyfa, vert grunntalet 10 brukt.

#### Eksempel

=LOG(10; 3) returnerer tretalslogaritmen av 10 (ca. 2,0959).

=LOG(7^4;7) returnerer 4.

## MFM_EXCEL2003 (LCM_EXCEL2003 på engelsk)

Returnerer minste felles multiplum for ei liste av tal.

Funksjonane som har eit namn som endar med _ADD eller _EXEL2003 returnerer det same resultatet som dei tilsvarande funksjonane i Microsoft Excel 2003 (utan denne endinga). Bruk dei same funksjonane utan endinga for å få resultat basert på internasjonal standard.

#### Syntaks

MFM_EXCEL2003(tal 1[; tal 2[; … ;tal 254]]])

Nummer 1; Nummer 2; … ; Nummer 255 er tal, referansar til celler eller til celleområde med tal.

#### Eksempel

=MFM_EXCEL2003(5;15;25) returnerer 75.

## MFM (LCM på engelsk)

Returnerer minste felles multiplum til eitt eller fleire heiltal.

#### Syntaks

MFM(Heiltal1[; Heiltal2][; …;[Heiltal255]])

Heiltal 1; Heiltal 2; … ; Heiltal 255 er heiltal, referansar til celler eller til celleområde av heiltal.

Denne funksjonen ignorerer all tekst og tomme celle innføre eit dataområde. Har du mistanke om feil resultat frå denne funksjonen, ser du etter tekst i dataområda. For å utheva tekstinnhald i dataområdet, brukar du funksjonen verdimerking.

#### Eksempel

Viss du skriv inn tala 512; 1024 og 2000 som heiltala 1; 2 og 3 vert 128000 returnert.

## MRUND (MROUND på engelsk)

Returnerer eit tal avrunda til det næraste multiplum av eit anna tal.

#### Syntaks

MRUND(Verdi; Multiplum)

Returnerer Verdi avrunda til næraste multiplum av Multiplum.

Ei alternativ implementering ville vore Multiplum * AVRUND(Verdi/Multiplum).

#### Eksempel

=MRUND(15,5; 3) returnerer 15, sidan 15,5 er nærare 15 (= 3*5) enn 18 (= 3*6).

=MRUND(1,4; 0,5) returnerer 1,5 (= 0,5*3).

## MULTINOMINELL (MULTINOMINAL på engelsk)

Returnerer fakultetet av summen av argumenta delt på produktet av fakulteta av argumenta.

#### Syntaks

MULTINOMINELL(tal 1[; tal 2[; … ;tal 254]]])

Nummer 1; Nummer 2; … ; Nummer 255 er tal, referansar til celler eller til celleområde med tal.

Denne funksjonen ignorerer all tekst og tomme celle innføre eit dataområde. Har du mistanke om feil resultat frå denne funksjonen, ser du etter tekst i dataområda. For å utheva tekstinnhald i dataområdet, brukar du funksjonen verdimerking.

#### Eksempel

=MULTINOMINELL(F11:H11) returnerer 1260 viss F11 til H11 indeheld verdiane 2, 3 og 4. Dette svarar til formlen =(2+3+4)! / (2!*3!*4!)

## OPPHØG (POWER på engelsk)

Returnerer eit tal opphøgd til eit anna tal.

#### Syntaks

OPPHØG(Grunntal; Eksponent)

Returnerer Grunntal opphøgd til eksponenten Eksponent.

Du kan oppnå det same resultatet ved å bruka eksponentieringsoperatøren ^: base ^eksponent

=OPPHØGD.I(0;0) returnerer 1; =OPPHØGD.I(0;X) rapporterer feilen #NUM! når eksponenten X er negativ.

= OPPHØGD.I(B, X) kan rapportera eller ikkje rapportera ein #NUM!-feil når B er negativ og X ikkje er eit heiltall.

#### Eksempel

= OPPHØGD.I(4; 3) Returnerer 64, som er 4 opphøgd i 3.

= 4^3 Returnerer også 4 opphøgd i 3.

=OPPHØGD.I(2;-3) returnerer 0,125.

=OPPHØGD.I(-2;1/3) returnerer -1,25992104989487.

= OPPHØGD.I(-2; 2/3) Returnerer #NUM!-feilen.

## PI

Returnerer 3,14159265358979 som er verdien av den matematiske konstanten Pi med 14 desimalar.

#### Syntaks

PI()

#### Eksempel

=PI() returnerer 3,14159265358979.

## PRODUKT

Multipliserer alle tala gjevne som argument og returnerer produktet.

#### Syntaks

PRODUKT(tal 1[; tal 2[; … ;tal 254]]])

Nummer 1; Nummer 2; … ; Nummer 255 er tal, referansar til celler eller til celleområde med tal.

Denne funksjonen ignorerer all tekst og tomme celle innføre eit dataområde. Har du mistanke om feil resultat frå denne funksjonen, ser du etter tekst i dataområda. For å utheva tekstinnhald i dataområdet, brukar du funksjonen verdimerking.

#### Eksempel

=PRODUKT(2;3;4) returnerer 24.

## RADIANAR (RADIANS på engelsk)

Gjer om grader til radianar.

#### Syntaks

RADIANAR(Tal)

Tal er vinklen i grader som skal konverterast til radianar.

#### Eksempel

=RADIANAR(90) returnerer 1,5707963267949, som er pi/2 med Calcs presisjon.

## REST (MOD på engelsk)

Returnerer resten ved divisjon av eit heiltal med eit anna heiltal.

#### Syntaks

REST(Dividend; Divisor)

For heiltalsargument vil denne funksjonen returnera Dividend modulo Divisor, det vil seia resten når Dividend er dividert med Divisor.

Denne funksjonen er implementert som Teljar - Nemnar * HEILTAL(Teljar/Nemnar) og denne formelen gjev resultatet dersom argumenta ikkje er heiltal.

#### Eksempel

=REST(22; 3) returnerer 1, resten når 22 vert dividert med 3.

=REST(11,25;2,5) returnerer 1,25.

## ROTPI (SQRTPI på engelsk)

Returnerer kvadratrota av (pi gongar eit tal).

#### Syntaks

ROTPI(Tal)

Returnerer den positive kvadratrota av (PI gongar Tal).

Dette er det same som KVROT(PI()*Tal).

#### Eksempel

=ROTPI(2) returnerer kvadratrota av (2pi), omlag 2,506628.

## SEKANT (SEC på engelsk)

Returnerer sekanten av ein gjeven vinkel (i radianar). Sekanten av ein vinkel svarar til 1 dividert med cosinus til vinkelen.

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 3.5.

#### Syntaks

SEKUND(Tal)

Returnerer (den trigonometriske) sekanten av Tal, vinkelen i radianar.

For å returnera sinusen av ein vinkel i grader, kan du bruka funksjonen RADIANAR.

#### Eksempel

=SEKANT(PI()/4) returnerer den tilnærma verdien 1.4142135624, som er inversen av cosinus av PI/4 radianar.

=SEKANT(RADIANAR(60)) returnerer 2, sekanten av 60 grader.

## SFF_EXCEL2003 (GCD_EXCEL2003 på engelsk)

Returnerer den største felles divisoren for ei liste av tal.

Funksjonane som har eit namn som endar med _ADD eller _EXEL2003 returnerer det same resultatet som dei tilsvarande funksjonane i Microsoft Excel 2003 (utan denne endinga). Bruk dei same funksjonane utan endinga for å få resultat basert på internasjonal standard.

#### Syntaks

SFF_EXCEL2003(tal 1[; tal 2[; … ;tal 254]]])

Nummer 1; Nummer 2; … ; Nummer 255 er tal, referansar til celler eller til celleområde med tal.

#### Eksempel

=SFF_EXCEL2003(5;15;25) returnerer 5.

## SFF (GCD på engelsk)

Returnerer den største felles faktoren (også kalla største felles divisor) til to eller fleire heiltal.

Samnemnaren er det største positive heiltalet som går opp i kvart av dei gjevne tala utan rest.

#### Syntaks

SFF(Heiltal1[; Heiltal2][; …;[Heiltal255]])

Heiltal 1; Heiltal 2; … ; Heiltal 255 er heiltal, referansar til celler eller til celleområde av heiltal.

Denne funksjonen ignorerer all tekst og tomme celle innføre eit dataområde. Har du mistanke om feil resultat frå denne funksjonen, ser du etter tekst i dataområda. For å utheva tekstinnhald i dataområdet, brukar du funksjonen verdimerking.

#### Eksempel

=SFF(16;32;24) returnerer resultatet 8, fordi 8 er det største talet som går opp i 16, 24 og 32 utan å gje ein rest.

=SFF(B1:B3) der cellene B1, B2, B3 indeheld 9, 12, 9 vert 3.

## SIN

Returnerer sinus av den gjevne vinkelen (i radianar).

#### Syntaks

SIN (tal)

Returnerer (den trigonometriske) sinusen av Tal, vinkelen i radianar.

For å returnera sinusen av ein vinkel i grader kan du bruka funksjonen RADIANAR.

#### Eksempel

=SIN(PI()/2) returnerer 1, sinus til pi/2 radianar.

=SIN(RADIANAR(30)) returnerer 0,5, sinus av 30 grader.

## SINH (SINH på engelsk)

Returnerer hyperbolsk sinus til eit tal.

#### Syntaks

SINH(tal)

Returnerer den hyperbolske sinus av Tal.

#### Eksempel

=SINH(0) returnerer 0, den hyperbolske sinus av 0.

## SUMMERKVADRAT (SUMSQ på engelsk)

Reknar ut summen av kvadrata av eit sett med tal.

#### Syntaks

SUMMERKVADRAT(tal 1[; tal 2[; … ;tal 254]]])

Nummer 1; Nummer 2; … ; Nummer 255 er tal, referansar til celler eller til celleområde med tal.

Denne funksjonen ignorerer all tekst og tomme celle innføre eit dataområde. Har du mistanke om feil resultat frå denne funksjonen, ser du etter tekst i dataområda. For å utheva tekstinnhald i dataområdet, brukar du funksjonen verdimerking.

#### Eksempel

Skriv du inn tala 2; 3 og 4 som argument nummer 1; 2 og 3, vert resultatet 29 returnert.

## SUMMER.REKKJE (SERIESSUM på engelsk)

Summerer dei første elementa av ein serie med potensar.

SUMMER.REKKJE(x;n;m;c) = c1xn + c2xn+m + c3xn+2m + ... + cixn + (i-1)m.

#### Syntaks

SUMMER.REKKJE(X; N; M; Koeffisientar)

X er innverdien for potensrekka.

N er startpotensen

M er opphøginga av N

Koeffisientar er ei rad av koeffisientar. For kvar koeffisient vert summen i rada utvida med ein seksjon.

#### Eksempel

=SUMMER.REKKJE(A1; 0; 1; {1; 2; 3}) reknar ut verdien av 1+2x+3x2,der x er verdien i celle A1. Viss A1 inneheld 1, returnerer formelen 6; viss A1 inneheld 2, returnerer formelen 17; viss A1 inneheld 3, returnerer formelen 34 og så vidare.

Sjå wikisida SERIESUM for meir om denne funksjonen (på engelsk).

## TANH (TANH på engelsk)

Returnerer hyperbolsk tangens til eit tal.

#### Syntaks

TANH(tal)

Returnerer den hyperbolske tangens av Tal.

#### Eksempel

=TANH(0) returnerer 0, den hyperbolske tangens av 0.

## TAN (TAN på engelsk)

Returnerer tangens av den gjevne vinkelen (i radianar).

#### Syntaks

TAN(tal)

Returnerer (den trigonometriske) tangens av tal, vinkelen i radianar.

For å returnera tangens av ein vinkel i grader kan du bruka funksjonen RADIANAR.

#### Eksempel

=TAN(PI()/4) returnerer 1, tangens av pi/4 radianar.

=TAN(RADIANAR(45)) returnerer 1, tangens til 45 grader.

## TILFELDIG

Returnerer eit tilfeldig tal mellom 0 og 1.

Denne funksjonen vert alltid rekna ut på nytt når arket vert rekna ut på nytt.

#### Syntaks

TILFELDIG()

Denne funksjonen lagar eit nytt, tilfeldig tal kvar gong Calc reknar ut på nytt. Du kan tvinga Calc til å rekna ut på nytt ved å trykkja på tasten F9.

For å generera tilfeldige tal som ikkje vert rekna ut på nytt, bruk anten

- Kopier cellene som inneheld =TILFELDIG() og bruk Rediger → Lim inn utval (med Lim inn alt og Formlar umerkte og Tal merkt).

- Bruk kommandoen for å fylle celler med tilfeldige tal (Ark → Fyll celler → Fyll inn tilfeldige tal).

- Bruk funksjonen TILFELDIG.NV() for ikkje-flyktige tilfeldige tal.

#### Eksempel

=TILFELDIG() returnerer eit tilfeldig tal mellom 0 og 1.

## TILFELDIGMELLOM

Returnerer eit tilfeldig heiltal i eit gjeve område.

Denne funksjonen vert alltid rekna ut på nytt når arket vert rekna ut på nytt.

#### Syntaks

TILFELDIGMELLOM (Botn; Topp)

Returnerer eit tilfeldig heiltal mellom heiltala Botn og Topp (begge inklusive).

Denne funksjonen lagar eit nytt, tilfeldig tal kvar gong Calc reknar ut på nytt. Du kan tvinga Calc til å rekna ut på nytt ved å trykkja på tasten F9.

For å laga tilfeldige tal som aldri vert rekna ut på nytt, kopier cellene som inneheld denne funksjonen og bruk Rediger → Set inn Spesiell (med Set inn alt og ikkje Formlar merkte og Tal merkte).

#### Eksempel

=TILFELDIGMELLOM (20;30) returnerer eit heiltal mellom 20 og 30.

## TILFELDIGMELLOM.NV

Returnerer eit ikkje-flyktig tal innføre eit spesifisert område.

#### Syntaks

TILFELDIGMELLOM.NV(Botn; Topp)

Returnerer eit ikkje-flyktig tilfeldig heiltal mellom heiltala Botn og Topp (begge medrekna). Ein ikkje-flyktig funksjon vert ikkje rekna ut på nytt ved nye inndata eller trykk på F9. Funksjonen vert derimot rekna ut på nytt når du trykkjer på F9 med markøren på cella som inneheld funksjonen, når du opnar fila, når du brukar kommandoen Hard omrekning(Shift + Kommando Ctrl + F9) og når Topp eller Botn vert rekna ut på nytt.

#### Eksempel

=TILFELDIGMELLOM.NV(20;30) returnerer eit ikkje-volatilt heiltal mellom 20 og 30.

=TILFELDIGMELLOM.NV(A1;30) returnerer eit ikkje-volatilt heiltal mellom verdien i cella A1 og 30. Funksjonen vert rekna ut på nytt når verdien i cella A1 vert endra.

#### Teknisk informasjon

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 7.0.

Denne funksjonen er ikkje ein del av standarden Open Document Format for kontorprogram (OpenDocument) Versjon 1.3. del 4: Omrekna formel (OpenFormula)-format. Namnerommet er

ORG.LIBREOFFICE.RANDBETWEEN.NV

## TILFELDIG.NV

Returnerer eit ikkje-flyktig tal mellom 0 og 1.

#### Syntaks

TILFELDIG.NV()

Denne funksjonen lagar eit ikkje-flyktigt, tilfeldig tal ved innskrivinga. Ein ikkje-flyktig funksjon vert ikkje rekna ut på nytt ved nye innskrivingar. Funksjonen vert ikkje rekna ut på nytt når du trykkjer på F9, unnateke når markøren er på den cella som inneheld funksjonen eller du brukar kommandoen Hard omrekning(Skift + Kommando Ctrl + F9). Funksjonen vert rekna ut på nytt når fila vert opna.

#### Eksempel

=TILFELDIG.NV() returnerer eit ikkje-flyktig tal mellom 0 og 1.

#### Teknisk informasjon

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 7.0.

Denne funksjonen er ikkje ein del av standarden Open Document Format for kontorprogram (OpenDocument) Versjon 1.3. del 4: Omrekna formel (OpenFormula)-format. Namnerommet er

ORG.LIBREOFFICE.RAND.NV

Liknande emne

Funksjonar etter kategori

Støtt oss!