Innhald

# ScriptForge.Array-teneste

Inneheld ei samling metodar for å redigera og transformera matriser med éin dimensjon (vektorar) og matriser med to dimensjonar. Dette gjeld også sett-operasjonar, sortering, import frå og eksport til tekstfiler.

Matriser med meir enn to dimensjonar kan ikkje brukast med metodane i denne tenesta. Einaste unntaket er metoden CountDims, som godtar matriser med kor mange dimensjonar som helst.

Matrise-element kan innehalda kva verdi som helst, også (under)matriser.

## Oppkall av tenester

Før du kan bruka tenesta Array, må du henta inn biblioteket ScriptForge ved hjelp av

        GlobalScope.BasicLibraries.loadLibrary("ScriptForge")

Lastinga av biblioteket vil laga objektet SF_Array som kan brukast for å kalla opp metodane i tenesta Array.

Desse kodesnuttane viser dei ulike måtane å kalla opp metodar på i tenesta Array. Metoden Append er brukt som eksempel:

        Dim arr : arr = Array(1, 2, 3)
        arr = SF_Array.Append(arr, 4)

        Dim arr : arr = Array(1, 2, 3)
        Dim svc : svc = SF_Array
        arr = svc.Append(arr, 4)

        Dim arr : arr = Array(1, 2, 3)
        Dim svc : svc = CreateScriptService("Array")
        arr = svc.Append(arr, 4)

Fordi Python har innebygd støtte for liste og tuplar, er dei fleste metodane i Matrise-tenesta berre tilgjengeleg for grunnleggjande skript. Det einaste unntaket er ImportFromCSVFile som vert støtta både i Basic og Python.

Liste over metodar i tenesta matrise
Append AppendColumn AppendRow Contains ConvertToDictionary Copy CountDims Difference ExportToTextFile ExtractColumn ExtractRow | Flatten ImportFromCSVFile IndexOf Insert InsertSorted Intersection Join2D Prepend PrependColumn PrependRow RangeInit | Reverse Shuffle Slice Sort SortColumns SortRows Transpose TrimArray Union Unique

Det første argumentet i dei fleste metodane er kva matriseopbjekt som skal vurderast. Den vert alltid sendt med referanse og vert ikkje endra. Metodar som «Append», «Prepend» osv. returnerer eit nytt matrise-objekt etter utføringa.

## Append

Legg elementa som er oppførte til som argument på slutten av inndatamatrisa.

### Syntaks:

svc.Append(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

### Parametrar:

matrise_1d: matrisa som finst frå før, kan vera tom.

arg0, arg1, ...: Elementer som vert lagt til matrise_1d.

### Eksempel:

        Dim a As Variant
        a = SF_Array.Append(Array(1, 2, 3), 4, 5)
            ' (1, 2, 3, 4, 5)

## AppendColumn

Set inn ein ny kolonne til høgre i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

### Syntaks:

svc.AppendColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

### Parametrar:

Matrise_2D: Matrisa som finst frå før, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den første kolonnen i den resulterande todimensjonale matrisa.

kolonne: ei eindimensjonal matrise med like mange element som det er rader i matrise_2d.

### Eksempel:

        Dim a As Variant, b As variant
        a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
            ' ((1, 4), (2, 5), (3, 6))
        b = SF_Array.AppendColumn(a, Array(7, 8, 9))
            ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
        c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
            ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i

## AppendRow

Legg til ei ny rad nedst i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege matrisa.

### Syntaks:

svc.AppendRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*])

### Parametrar:

Matrise_2d: Matrisa som finst frå før. Kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den første rada i den nye todimensjonale matrisa.

Rad: Ei eindimensional matrise med like mange element som det er rader i matrise_2d.

### Eksempel:

        Dim a As Variant, b As variant
        a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
            '  ((1, 2, 3), (4, 5, 6))
        b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
            ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i

## Contains

Sjå etter om ei eindimensjonal matrise inneheld eit bestemt tal, ein bestemt tekst eller dato. Tekstsamanlikningar kan skilja mellom store og små bokstavar.
Sorterte inndatamatriser må fyllast ut homogent, det vil seia at alle elementa må vera skalarar av same type (Tomme- og Null-element kan ikkje brukast).
Det er uråd å vita på førehand kva resultatet av metoden vert når matrisa er sagt å vera sortert utan at ho er det.
Det vert utført eit binærsøk når matrisa er sortert, elles vert ho skanna frå øvst til nedst og Tomme element og Nullelement vert ignorerte.

### Syntaks:

svc.Contains(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ""): bool

### Parametrar:

matrise_1d: Matrisa som skal skannast.

ÅFinna: Eit tal, ein dato eller ein streng som skal finnast.

skilje mellom store og små bokstavar: Berre for strengsamanlikningar (Standard = Usann).

sorteringsrekkjefølgje: Det kan anten vera "ASC", "DESC" eller "" (ikkje sortert). Standardverdien er "".

### Eksempel:

        Dim a As Variant
        a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
        SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False

## ConvertToDictionary

Lagrar innhaldet av ei matrise med to kolonnar i eit ScriptForge.Dictionary-objekt.
Nøkkelen vert henta ut frå den første kolonnen, elementet frå den andre.

### Syntaks:

svc.ConvertToDictionary(array_2d: any[0..*, 0..1]): obj

### Parametrar:

matrise_2d: Data som skal konverterast til eit ScriptForge.Dictionary-objekt.

- Den første kolonnen må berre innehalda strengar med lengd større enn null, i kva rekkjefølgje som helst. Desse verdiane vert brukte som etikettar i ordboka.

- Den andre kolonnen innehald dataa som skal knytast til den tilsvarande etiketten i ordboka.

### Eksempel:

        Dim a As Variant, b As Variant
        a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
        b = SF_Array.ConvertToDictionary(a)
        MsgBox b.Item("c") ' 3

## Copy

Lagar ein kopi av ei 1D- eller 2D-matrise.

### Syntaks:

svc.Copy(array_nd: any[0..*]): any[0..*]

svc.Copy(array_nd: any[0..*, 0..*]): any[0..*, 0..*]

### Parametrar:

matrise_nd: 1D- eller 2D-matrisa som skal kopierast.

### Eksempel:

Ei enkel tilordning av eit matrise-objekt vil kopiera referansen i staden for å laga ein kopi av innhaldet i objektet. Sjå eksempelet nedanfor:

        Dim a as Variant, b as Variant
        a = Array(1, 2, 3)
        ' Tilordninga nedanfor er laga ved referanse
        b = a
        ' Difor vil endring av verdiar i «b» også endra «a»
        b(0) = 10
        MsgBox a(0) ' 10

Ved å bruka metoden Copy, vert det laga ein kopi av heile Array-objektet. I eksempelet nedanfor er a og b ulike objekt. Endring av verdiar i b vil ikkje påverka verdiane i a .

        Dim a as Variant, b as Variant
        a = Array(1, 2, 3)
        ' Lagar ein kopi av "a" ved å bruka "Copy"-metoden
        b = SF_Array.Copy(a)
        b(0) = 10
        MsgBox a(0) ' 1

## CountDims

Tel kor mange dimensjonar ei matrise har. Resultatet kan vera større enn to
Viss argumentet ikkje er ein streng, vert det returnert -1
Viss matrisa ikkje er initialisert, vert det returnert 0.

### Syntaks:

svc.CountDims(array_nd: any): int

### Parametrar:

array_nd: matrisa som skal granskast.

### Eksempel:

        Dim a(1 To 10, -3 To 12, 5)
        MsgBox SF_Array.CountDims(a) ' 3

## Difference

Bygg eit sett som ei null-basert matrise, ved å bruka differensoperatoren på dei to inndatamatrisene. Resulterande element kjem frå den første matrisa og ikkje frå den andre.
Den resulterande matrisa vert sortert i stigande rekkjefølgje.
Begge inndatamatrisene må fyllast homogent, elementa må vera skalarar av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

### Syntaks:

svc.Difference(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

### Parametrar:

array1_1d : Ei eindimensjonal referansematrise der elementa vert granska for om dei kan fjernast.

array2_1d : Ei eindimensjonal matrise der elementa vert dregne frå den første inndatamatrisa.

casesensitive: Gjeld berre viss matrisene er fylte med strenger (standard = Usann).

### Eksempel:

        Dim a As Variant
        a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
            ' ("A", "B")

## ExportToTextFile

Skriv alle matriseelementa i nummerrekkjefølgje til ei tekstfil. Viss fila finst frå før, vert ho overskrive utan varsel.

### Syntaks:

svc.ExportToTextFile(array_1d: any[0..*], filename: str, [encoding: str]): bool

### Parametrar:

array_1d: Matrisa som skal eksporterast. Ho må innehalda berre strengar.

filename: Namnet på tekstfila som dataa skal skrivast til. Namnet må vera i samsvar med den gjeldande FileNaming-eigenskapen til SF_FileSystem-tenesta.

encoding: Teiknsettet som skal brukast. Bruk eitt av namna som er oppførte i IANA-teiknsett. Merk at LibreOffice kanskje ikkje implementerer alle teiknsetta som finst (standard er «UTF-8»).

### Eksempel:

        SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")

## ExtractColumn

Trekk ut ein bestemt kolonne frå ei todimensjonal matrise som ei ny matrise.
Dei nedre LBound og øvre UBound grensene er dei same som dei brukte i første dimensjon av innmatrisa.

### Syntaks:

svc.ExtractColumn(array_2d: any[0..*, 0..*], columnindex: int): any[0..*, 0..*]

### Parametrar:

array_2d : Matrisa som det skal trekkjast ut frå.

columnindex : Nummeret på kolonnen som skal trekkjast ut – må vera i intervallet [LBound, UBound].

### Eksempel:

        'Lagar ei 3 × 3 matrise: |1, 2, 3|
        '                      |4, 5, 6|
        '                      |7, 8, 9|
        Dim mat as Variant, col as Variant
        mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
        mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
        mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
        'Trekk ut den tredje kolonnen: |3, 6, 9|
        col = SF_Array.ExtractColumn(mat, 2)

## ExtractRow

Trekk ut ei bestemt rad som ei ny matrise frå ei to-dimensjonal matrise.
Nedre (LBound) og øvre (UBound) grense er lik grensene i den andre dimensjonen i inndatamatrisa.

### Syntaks:

svc.ExtractRow(array_2d: any[0..*, 0..*], rowindex: int): any[0..*, 0..*]

### Parametrar:

array_2d : Matrisa som det skal trekkjast ut frå.

rowindex: Nummeret på den rada som skal trekkjast ut – må vera i intervallet [LBound, UBound].

### Eksempel:

        ' Lagar ei 3 × 3 matrise: |1, 2, 3|
        '                      |4, 5, 6|
        '                      |7, 8, 9|
        Dim mat as Variant, row as Variant
        mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
        mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
        mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
        ' Trekk ut den første rada: |1, 2, 3|
        row = SF_Array.ExtractRow(mat, 0)

## Flatten

Stablar alle enkeltelementa i ei matrise og alle elementa i delmatrisene i éi ny matrise utan delmatriser. Tomme delmatriser vert ignorerte og delmatriser med større dimensjonar enn éin vert ikkje slått saman.

### Syntaks:

svc.Flatten(array_1d: any[0..*]): any[0..*]

### Parametrar:

array_1d: Matrisa som finst frå før, kan vera tom.

### Eksempel:

        Dim a As Variant
        a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
            ' (1, 2, 3, 4, 5)

Du kan bruka metoden Flatten saman med andre metodar som for eksempel Append eller Prepend for å kopla saman eit sett med 1D-matriser til éi enkelt 1D-matrise.

### Eksempel:

Neste eksempel viser korleis metodane Flatten og Append kan kombinerast for å setja saman tre matriser.

        ' Lagar tre matriser for dette eksempelet
        Dim a as Variant, b as Variant, c as Variant
        a = Array(1, 2, 3)
        b = Array(4, 5)
        c = Array(6, 7, 8, 9)
        ' Slår saman dei tre matrisene til éi 1D-matrise
        Dim arr as Variant
        arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
        '(1, 2, 3, 4, 5, 6, 7, 8, 9)

## ImportFromCSVFile

Importer dataa frå ei kommadelt fil (CSV). Kommaet kan bytast ut med kva teikn som helst.

Det aktuelle CSV-formatet er forklart i IETF Common Format and MIME Type for CSV Files.

Kvar linje i fila inneheld ein fullstendig post (linjedeling er ikkje tillate).
Sekvensar som \n, \t, … vert uendra. Bruk SF_String, Unescape()-metoden for å administrera dei.

Metoden returnerer ei matrise med to dimensjonar der radene svarar til éin enkelt post i fila, og der kolonnane svarar til eitt felt i posten. Det vert ikkje kontrollert om felttypane er samanhengande på tvers av kolonnar. Det vert gjort ei beste gissing for å identifisera numeriske typar og datotypar.

Viss ei linje inneheld færre eller fleire felt enn den første linja i fila, vert det sett eit unntak. Tomme linjer vert ganske enkelt ignorerte. Viss fila er større enn grensa for talet på element (sjå i koden), vert det vist ei åtvaring og matrisa vert avkorta.

### Syntaks:

svc.ImportFromCSVFile(filename: str, delimiter: str = ',', dateformat: str = ''): any[0..*]

### Parametrar:

filename: Namnet på tekstfila som inneheld dataa. Namnet må vera i samsvar med den gjeldande FileNaming-eigenskapen til SF_FileSystem-tenesta.

delimiter: eitt enkelt teikn, som oftast eit komma, eit semikolon eller eit tabulatorteikn (standard = ",").

sateformat: Ein spesiell mekanisme handsamar datoar når dateformat er anten «ÅÅÅÅ-MM-DD», «DD-MM-ÅÅÅÅ» eller «MM-DD-ÅÅÅÅ». Streken (-) kan bytast ut med punktum (.), skråstrek (/) eller eit mellomrom. Andre datoformat vert ignorerte. Datoar i hermeteikn ("") vert sett på som vanleg tekst.

### Eksempel:

Tenk på CSV-fila "myFile.csv" med dette innhaldet:

Namn,Fødselsdato,Adresse,By

Anna,2002/03/31,"Rue de l'église, 21",Toulouse

Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne

Eksempla nedanfor i Basic og Python les innhaldet i CSV-fila inn i eit Array-objekt.

##### I Basic

        Dim arr As Variant
        arr = SF_Array.ImportFromCSVFile("C:\Temp\miFil.csv", DateFormat := "ÅÅÅÅ/MM/DD")
        MsgBox arr(0, 3) ' By
        MsgBox arr(1, 2) ' Rue de l'église, 21
        MsgBox arr(1, 3) ' Toulouse

##### I Python

        from scriptforge import CreateScriptService
        svc = CreateScriptService("Array")
        bas = CreateScriptService("Basic")
        arr = svc.ImportFromCSVFile(r"C:\Temp\myFile.csv", dateformat = "ÅÅÅÅ/MM/DD")
        bas.MsgBox(arr[0][3]) # By
        bas.MsgBox(arr[1][2]) # Rue de l'église, 21
        bas.MsgBox(arr[1][3]) # Toulouse

## IndexOf

Sjå etter eit tal, ein streng eller ein dato i ei eindimensjonal matrise. Tekstsamanlikning kan skilja mellom store og små bokstavar, eller ikkje.
Viss matrisa er sortert, må ho vera utfylt homogent, altså at alle elementa må vera skalarar av same type (Empty og Null kan ikkje brukast).
Når matrisa er sett til å vera sortert men ikkje er det, er det uråd å vita resultatet på førehand.
Det vert brukt binært søk på sorterte matriser. Elles vert matriser ganske enkelt skanna frå topp til botn. Elementa Empty og Null vert ikkje tekne med.
Metoden returnerer LBound(input array) - 1 viss søket ikkje var vellukka.

### Syntaks:

svc.IndexOf(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ''): int

### Parametrar:

array_1d: Matrisa som skal skannast.

tofind: Eit tal, ein dato eller ein streng som skal finnast.

casesensitive: Berre for strengsamanlikningar (standard = Usann).

sorteringsrekkjefølgje: Det kan anten vera "ASC", "DESC" eller "" (ikkje sortert). Standardverdien er "".

### Eksempel:

        MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
        MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1

## Insert

Set inn elementa som er oppført som argument framføre ein gjeven indeks for inndatamatrisa.
Argument vert sette inn blindt. Kvart av dei kan anten vera ein skalar av kva type som helst eller ei undermatrise.

### Syntaks:

svc.Insert(array_1d: any[0..*], before: int, arg0: any, [arg1: any] ...): any[0..*]

### Parametrar:

array_1d: Matrisa som finst frå før, kan vera tom.

before: Indeksen som skal setjast inn framføre må vera i intervallet [LBound, UBound + 1].

arg0, arg1, …: Element som vert sette inn i matrise_1d.

### Eksempel:

        Dim a As Variant
        a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
            ' (1, 2, "a", "b", 3)

## InsertSorted

Set inn eit nytt element på plassen sin i ei sortert matrise.
Matrisa må fyllast homogent, altså at alle elementa må vera skalarer av same type.
Elementa Empty og Null er ikkje tillatne.

### Syntaks:

svc.InsertSorted(array_1d: any[0..*], item: any, sortorder: str = 'ASC', casesensitive: bool = False): any[0..*]

### Parametrar:

matrise_1d: Matrisa som verdien skal setjast inn i.

Element: Skalarverdien som skal setjast inn. Av same type som matriseelementa som finst frå før.

sorteringsrekkjefølgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og små bokstavar: Berre for strengsamanlikningar (Standard = Usann).

### Eksempel:

        Dim a As Variant
        a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
            ' ("A", "B", "C", "a", "b")

## Intersection

Bygg eit sett som ei null-basert matrise ved å bruka unionmengde-operatoren på dei to inndatamatrisene. Resulterande element kjem frå begge matrisene.
Den resulterande matrisa vert sortert i stigande rekkjefølgje.
Begge inndatamatrisene må fyllast homogent, elementa må vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

### Syntaks:

svc.Intersection(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

### Parametrar:

array1_1d: Den første inndatamatrisa.

array2_1d: Den andre inndatamatrisa.

skil mellom store og små bokstavar: Gjeld for matriser fylt med tekstelement (standard = Usann).

### Eksempel:

        Dim a As Variant
        a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
            ' ("C", "b")

## Join2D

Føyer saman ei todimensjonal matrise med to skiljeteikn, eitt for kolonnane, eitt for radene.

### Syntaks:

svc.Join2D(array_2d: any [0..*, 0..*], [columndelimiter: str], [rowdelimiter: str], [quote: str]): str

### Parametrar:

array_2d: Kvart element må vera anten tekst, eit tall, ein dato eller ein boolsk verdi.
Datoar vert omforma til formatet ÅÅÅÅ-MM-DD tt:mm:ss.
Ugyldige element vert byt ut med ein streng med null lengd.

Kolonneskiljeteikn: Skilje mellom kolonnar (standard = Tab/Chr(9)).

Radskiljeteikn: Skil mellom radene (standard = LineFeed/Chr(10))

Hermeteikn: viss Sann vert strengen verna med doble hermeteikn ("). Standarden er Usann.

### Eksempel:

        ' arr = | 1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5           |
        '       | 6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10 |
        Dim arr as Variant : arr = Array()
        arr = SF_Array.AppendRow(arr, Array(1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5))
        arr = SF_Array.AppendRow(arr, Array(6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10))
        Dim arrText as String
        arrText = SF_Array.Join2D(arr, ",", "/", False)
        ' 1,2,A,,51,2,A,,5/6,7,this is a string,9,106,7,this is a string,9,10

## Prepend

Legg dei utlista elementa til som argument i byrjinga av inndatamatrisa.

### Syntaks:

svc.Prepend(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

### Parametrar:

matrise_1d: matrisa som finst frå før, kan vera tom.

arg0, arg1 …: ei liste over element som skal setjast inn først i Matrise_1d.

### Eksempel:

        Dim a As Variant
        a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
            ' (4, 5, 1, 2, 3)

## PrependColumn

Legg til ein ny kolonne først på venstre side i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

### Syntaks:

svc.PrependColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

### Parametrar:

Matrise_2d: matrisa som finst frå før, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den første rada i den nye todimensjonale matrisa.

kolonne: ei eindimensional matrise med like mange element som det er rader i array_2d.

### Eksempel:

        Dim a As Variant, b As variant
        a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
            ' ((4, 1), (5, 2), (6, 3))
        b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
            ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i

## PrependRow

Legg til ei ny rad først i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

### Syntaks:

svc.PrependRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*]

### Parametrar:

matrise_2d: matrisa som finst frå før, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den siste rada i den nye todimensjonale matrisa.

Rad: ei eindimensional matrise med like mange element som det er rader i matrise_2d.

### Eksempel:

        Dim a As Variant, b As variant
        a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
            ' ((4, 5, 6), (1, 2, 3))
        b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
            ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i

## RangeInit

Initialiser ei ny null-basert matrise med numeriske verdiar.

### Syntaks:

svc.RangeInit(from: num, upto: num, [bystep: num]): num[0..*]

### Parametrar:

frå: verdien av det første elementet.

Opptil: Det siste elementet må ikkje overstige Opptil.

Trinnvis: Differansen mellom to etterfølgjande element (standard = 1).

### Eksempel:

        Dim a As Variant
        a = SF_Array.RangeInit(10, 1, -1)
            ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)

## Reverse

Returner den omvende eindimensjonelle inndata-matrisa.

### Syntaks:

svc.Reverse(array_1d: any[0..*]): any[0..*]

### Parametrar:

matrise_1d: matrisa som skal reverserast.

### Eksempel:

        Dim a As Variant
        a = SF_Array.Reverse(Array("a", 2, 3, 4))
            ' (4, 3, 2, "a")

## Shuffle

Returnerer ein tilfeldig permutasjon av ei eindimensjonal matrise.

### Syntaks:

svc.Shuffle(array_1d: any[0..*]): any[0..*]

### Parametrar:

matrise_1d: matrisa som skal blandast.

### Eksempel:

        Dim a As Variant
        a = SF_Array.Shuffle(Array(1, 2, 3, 4))
            ' Matrisa "a" er nå i tilfeldig rekkefølgje, f.eks. (2, 3, 1, 4)

## Slice

Returner eit delsett av ei eindimensjonal matrise.

### Syntaks:

svc.Slice(array_1d: any[0..*], from: int, [upto: int]): any[0..*]

### Parametrar:

matrise_1d: Matrisa som skal delast.

frå: Den lågaste indeksen i matrise_1d av delmatrisa som skal trekkjast ut (frå vert teken med.

opptil: Det øvste indeks i matrise_1d av den delmatrisa som det skal trekkjast ut frå (opptil medrekna). Standard = øvre grense for matrise_1d. Viss opptil < frå, vert det returnert ei tom matrise.

### Eksempel:

        Dim a As Variant
        a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)

## Sort

Sorter ei eindimensjonal matrise i stigande eller falande rekkjefølgje. Tekstsamanlikningar kan skilja mellom store og små bokstavar eller ikkje.
Matrisa skal vera fylt homogent, altså at elementa må vera av same type skalarar.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva skalarverdi som helst.

### Syntaks:

svc.Sort(array_1d: any[0..*], sortorder: str, casesensitive: bool = False): any[0..*]

### Parametrar:

matrise_1d: Matrisa som skal sorterast.

sorteringsrekkjefølgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og små bokstavar: Berre for strengsamanlikningar (Standard = Usann).

### Eksempel:

        Dim a As Variant
        a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
            ' ("A", "B", "C", "a", "b")

## SortColumns

Returner ein permutasjon av kolonnar i ei todimensional matrise, sortert etter verdiane i ei gjeven rad.
Rada må vera fylt homogent, altså at alle elementa må vera skalarer av same type.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva annan skalar verdi som helst.

### Syntaks:

svc.SortColumns(array_2d: any[0..*, 0..*], rowindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

### Parametrar:

matrise_2d: Den todimensjonale matrisa som skal sorterast.

radindeks: Indeksen til rada som skal brukast som referanse for å sortera kolonnane.

sorteringsrekkjefølgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og små bokstavar: Berre for strengsamanlikningar (Standard = Usann).

### Eksempel:

        ' arr = | 5, 7, 3 |
        '       | 1, 9, 5 |
        '       | 6, 1, 8 |
        Dim arr as Variant : arr = Array(5, 7, 3)
        arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
        arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
        arr = SF_Array.SortColumns(arr, 2, "ASC")
        ' arr = | 7, 5, 3 |
        '       | 9, 1, 5 |
        '       | 1, 6, 8 |

## SortRows

Returner ein permutasjon av kolonnar i ei todimensional matrise, sortert etter verdiane i ei gjeven rad.
Rada må vera fylt homogent, altså at alle elementa må vera skalarer av same type.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva annan skalar verdi som helst.

### Syntaks:

svc.SortRows(array_2d: any[0..*, 0..*], columnindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

### Parametrar:

matrise_1d: Matrisa som skal sorterast.

kolonneindeks: Indeksen til kolonnen som skal brukast som referanse for å sortera radene.

sorteringsrekkjefølgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og små bokstavar: Berre for strengsamanlikningar (Standard = Usann).

### Eksempel:

        ' arr = | 5, 7, 3 |
        '       | 1, 9, 5 |
        '       | 6, 1, 8 |
        Dim arr as Variant : arr = Array(5, 7, 3)
        arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
        arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
        arr = SF_Array.SortRows(arr, 0, "ASC")
        ' arr = | 1, 9, 5 |
        '       | 5, 7, 3 |
        '       | 6, 1, 8 |

## Transpose

Byter om rader og kolonnar i ei todimensjonal matrise.

### Syntaks:

svc.Transpose(array_2d: any[0..*, 0..*]): any[0..*, 0..*]

### Parametrar:

matrise_2d: Den todimensjonale matrisa som skal transponerast.

### Eksempel:

        ' arr1 = | 1, 2 |
        '        | 3, 4 |
        '        | 5, 6 |
        arr1 = Array(1, 2)
        arr1 = SF_Array.AppendRow(arr1, Array(3, 4))
        arr1 = SF_Array.AppendRow(arr1, Array(5, 6))
        arr2 = SF_Array.Transpose(arr1)
        ' arr2 = | 1, 3, 5 |
        '        | 2, 4, 6 |
        MsgBox arr2(0, 2) ' 5

## TrimArray

Fjern alle Null, Empty og null-lengd-oppføringar frå ei eindimensjonal matrise.
Strengelementa kan trimmast med funksjonen LibreOffice Basic Trim() .

### Syntaks:

svc.TrimArray(array_1d: any[0..*]): any[0..*]

### Parametrar:

matrise_1d: Matrisa som skal trimmast.

### Eksempel:

        Dim a As Variant
        a = SF_Array.TrimArray(Array("A", "B", Null, " D "))
            ' ("A", "B", "D")

## Union

Bygg eit sett som ei null-basert matrise ved å bruka unionmengde-operatoren på dei to inndatamatrisene. Resulterande element kjem frå ei av begge matrisene.
Den resulterande matrisa vert sortert i stigande rekkjefølgje.
Begge inndatamatrisene må fyllast homogent, elementa må vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og små bokstavar eller ikkje.

### Syntaks:

svc.Union(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

### Parametrar:

matrise1_1d: Den første inndatamatrisa.

matrise2_1d: Den andre inndatamatrisa.

skill mellom store og små bokstavar: Gjeld berre viss matrisene er fylte med strenger (standard = Usann).

### Eksempel:

        Dim a As Variant
        a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
            ' ("A", "B", "C", "Z", "b")

## Unique

Bygg eit sett av unike verdiar avleidde frå inndata-matrisa.
Inndata-matrisa må vera fylt homogent, altså at alle elementa må vera skalarer av den same typen. Elementa Empty og Null er ikkje tillatne.
Tekstsamanlikningar kan skilja mellom store og små bokstavar eller ikkje.

### Syntaks:

svc.Unique(array_1d: any[0..*], casesensitive: bool = False): any[0..*]

### Parametrar:

matrise_1d : Inndata-matrisa.

casesensitive: Gjeld berre viss matrisa er fylte med strengar (standard = Usann).

### Eksempel:

        Dim a As Variant
        a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
            '  ("A", "B", "C", "b")

Alle ScriptForge Basic-rutinane og -identifikatorane som vert innleidde med understrek «_» er reserverte for internt bruk. Dei er ikkje meint brukte i Basic-makroar.

Liknande emne

Tabellfunksjonar

Bruka Calc-funksjonar i makroar

Tenesta ScriptForge.Dictionary

Støtt oss!