Innhald

# Tenesta ScriptForge.Dictionary

Ei ordliste er ei samling av nøkkelelementpar

- Nøkkelen er ein streng. I Basic-skript vert innstillinga for å skilja mellom store og små bokstavar bestemt ved opprettinga av ordboka. I Python-skript skil nøkkelen alltid mellom store og små bokstavar.

- Elementa kan vera av kva type som helst

Nøklar og element kan hentast, teljast, oppdaterast og mykje meir.

Ordboktenesta liknar på det innebygde LibreOffice Basic-objektet Collection, men har fleire funksjonar. Såleis har ikkje Collection-objekta støtte for henting av nøklar. I tillegg har ordbøker tilleggsfunksjonar som å byta ut nøklar, kontrollera om ein bestemt nøkkel finst frå før og konvertera ordboka til ei matrise med «PropertyValues» eller ein JSON-streng.

## Oppkall av tenester

##### I Basic

Eksempelet nedføre opprettar myDict som ei tom ordbok.

        GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
        Dim myDict As Variant
        myDict = CreateScriptService("Dictionary", True)
                    ' Nøklane skil mellom store og små bokstavar, difor er det andre argumentet Sann

Det vert tilrådd å frigje ressursar etter bruk:

         Set myDict = myDict.Dispose()

##### I Python

Eksempelet nedanfor lagar eit tomt eksemplar av tenesta Dictionary og brukar metoden Python native update for å fylla det med innhaldet i eit Python dict-objekt .

        dico = dict('A' = 1, 'B' = 2, 'C' = 3)
        # Initialiser myDict som eit tomt ordboksobjekt
        myDict = CreateScriptService('Dictionary')
        # Les dico-verdiane inn i myDict
        myDict.update(dico)
        myDict['D'] = 4
        print(myDict)   # {'A': 1, 'B': 2, 'C': 3, 'D': 4}
        propval = myDict.ConvertToPropertyValues()

Det er mogleg å laga eit eksemplar av tenest Dictionary med Python-objektet dict som argument som vist i det følgjande eksempelet.

        dico = dict('A' = 1, 'B' = 2, 'C' = 3)
        # Initialiser myDict med innhaldet frå dico
        myDict = CreateScriptService('Dictionary', dico)
        myDict['D'] = 4
        print(myDict) # {'A': 1, 'B': 2, 'C': 3, 'D': 4}
        propval = myDict.ConvertToPropertyValues()

Fordi Python har innebygd ordbokstøtte, er dei fleste metodane i tenesta Dictionary berre tilgjengeleg for Basic-skript. Unnatak er ConvertToPropertyValues og ImportFromPropertyValues som vert støtta i både Basic og Python.

## Eigenskapar

Namn | Skriveverna | Type | Beskriving
--- | --- | --- | ---
Count | Ja | Long | Talet på oppføringar i ordboka
Items | Ja | Matrise med variantar | Lista over elementa som ei eindimensjonal matrise
Keys | Ja | Matrise av strengar | Lista over nøklar som ei eindimensjonal matrise

Eigenskapane Keys og Items returnerer deira respektive indhald i ei identisk rekkjefølgje. Rekkefølgja er ikkje relatert til rekkjefølgja sett ved opprettinga.

### Eksempel:

Det neste eksempelet brukar eigenskapen Keys for gå gjennom alle nøklane i myDict fleire gongar.

        Dim a As Variant, b As String
        a = myDict.Keys
        For Each b In a
            MsgBox(myDict.Item(b))
        Next b

Liste over metodar i ordboktenesta
Add ConvertToArray ConvertToJson ConvertToPropertyValues | Exists ImportFromJson ImportFromPropertyValues Item | Remove RemoveAll ReplaceItem ReplaceKey

## Add

Legg eit nytt nøkkelelementpar til ordboka. Returnerer Sann viss det lukkast.

### Syntaks:

dict.Add(key: str, item: any): bool

### Parametrar:

nøkkel: Strengverdi brukt til å identifisera elementet. Om nøkkelen skil mellom store og små bokstavar vart bestemt då ordboka vart oppretta.

element: Kva verdi som helst, også ei matrise, eit Basic-objekt, eit UNO-objekt, ei ordbok og så vidare.

### Eksempel:

          Dim NewValue As Variant
          myDict.Add("NewKey", NewValue)

Kvar nøkkel må vera unik i den same ordlista. Viss nøkkelen finst frå før i ordlista, vert det sett opp ein DUPLICATEKEYERROR. Nøklar som er laga av mellomromsteikn, vil setja opp feilen INVALIDKEYERROR.

## ConvertToArray

Lagrar innhaldet i ordboka i ei to-kolonnars, null-basert matrise. Nøklane er lagra i den første kolonnen og elementa i den andre kolonnen.

Viss ordboka er tom, vil denne metoden returnere ei tom matrise.

### Syntaks:

dict.ConvertToArray(): any[0..*, 0..1]

### Eksempel:

          Dim myDict as Variant
          myDict = CreateScriptService("Dictionary")
          myDict.Add("a", 1)
          myDict.Add("b", 2)
          myDict.Add("c", 3)
          Dim arr as Variant
          arr = myDict.ConvertToArray()
          '(("a", 1), ("b", 2), ("c", 3))

## ConvertToJson

Konverterer innhaldet i ordboka til tekst i JSON (JavaScript Object Notation).

### Avgrensingar

Denne metoden har støtte for desse datatypane: String, Boolean, numbers, Null og Empty. Matriser som inneheld element av desse er også tillatne, kva dimensjon dei måtte ha. Datoar vert konverterte til strengar som vert brukte i matrisene. Andre datatypar vert konverterte til det dei er representert med i strengen ved hjelp av tenesta SF_String.Represent.

### Syntaks:

dict.ConvertToJson(indent: str = ""): str

### Parametrar:

Innrykk: Når Indent er eit positivt tal eller ein tekst, vert JSON-matriseelement og objektelement skrivne ut med dette innrykket. Ein negativ verdi for Indent vil leggja til nye linjer utan innrykk. Standardverdien er ein tom streng "" som vel den mest kompakte representasjonen. Bruk av eit positivt heiltal for Indent vil setja inn så mange innrykk på nivået som talet seier. NårIndent er ein streng, for eksempel Chr(9 eller Tab(1), vert tabulator-teiknet brukt for innrykk på kvart nivå.

### Eksempel:

          myDict.Add("p0", 12.5)
          myDict.Add("p1", "a string àé""ê")
          myDict.Add("p2", DateSerial(2020,9,28))
          myDict.Add("p3", True)
          myDict.Add("p4", Array(1,2,3))
          MsgBox myDict.ConvertToJson()
          '{"p0": 12.5, "p1": "a string \u00e0\u00e9\"\u00ea", "p2": "2020-09-28", "p3": true, "p4": [1, 2, 3]}

## ConvertToPropertyValues

Lagrar innhaldet i ordlista i ei matrise med PropertyValues.

Kvar oppføring er ein com.sun.star.beans.PropertyValue. Nøkkelen er lagra i Name, elementet i Value.

Viss eitt av elementa har ein type Data, vert denne konvertert til ein com.sun.star.util.DateTime-struktur. Viss eitt av elementa er ei tom matrise, vert det konvertert til Null. Sluttmatrisa er tom når ordboka er tom.

### Syntaks:

dict.ConvertToPropertyValues(): obj[0..*]

### Eksempel:

##### I Basic

        Dim myDict as Variant
        myDict = CreateScriptService("Dictionary")
        ' Legg nokre eigenskapar til i ordboka
        myDict.Add("Color", "Blue")
        myDict.Add("Width", 20)
        ' Konverterer til ei matrise av objekta PropertyValue
        Dim prop as Variant
        prop = myDict.ConvertToPropertyValues()

##### I Python

Merk i eksempelet nedanfor at ei Python-ordliste må sendast vidare som det andre argumentet i metoden CreateScriptService.

        myDict = dict()
        myDict["Color"] = "Blue"
        myDict["Width"] = 30
        sfDic = CreateScriptService("Dictionary", myDict)
        prop = sfDic.ConvertToPropertyValues()

Mange tenester og metodar i UNO-biblioteket tek inn parametrar som er representerte med strukturen PropertyValue, som er ein del av LibreOffice API-en.

## Exists

Bestemmer om det finst ein nøkkel i ordboka.

### Syntaks:

dict.Exists(key: str): bool

### Parametrar:

nøkkel: Nøkkelen som skal slåast opp i ordboka.

### Eksempel:

        Dim myDict as Variant
        myDict = CreateScriptService("Dictionary")
        ' Legg nokre eigenskapar til i ordboka
        myDict.Add("Color", "Blue")
        myDict.Add("Width", 20)
        '(...)
        If Not myDict.Exists("Size") Then
           MsgBox "You have to provide a Size value"
        End If

## ImportFromJson

Legg til innhaldet av ein streng i JSON (JavaScript Object Notation) til i den gjeldande ordboka. Returnnerer Sann viss dette lukkast.

### Avgrensingar

JSON-strengen kan innehalda tal, tekst, boolske verdiar, nullverdiar og matriser som inneheld desse typane. Han kan ikkje innehald JSON-objekt, altså underordlister.

Det vert gjort eit forsøk på å omforma tekst til dato viss elementet passa med eitt av desse mønstera: ÅÅÅÅ-MM-DD, TT:MM:SS eller ÅÅÅÅ-MM-DD TT:MM:SS.

### Syntaks:

dict.ImportFromJson(inputstr: str, overwrite: bool = False): bool

### Parametrar:

inputStr: Strengen som skal importerast.

overskriv: Når Sann, kan oppføringar med same namn finnast i ordboka og verdiane deira overskrivast. Når Usann (standard), vil gjentekne tastar gje ei feilmelding. Ver merksam på at ordboknøklar ikkje skil mellom store og små bokstavar, medan namn gjer det i JSON-strengar.

### Eksempel:

        Dim s As String
        s = "{'firstName': 'John','lastName': 'Smith','isAlive': true,'age': 66, 'birth':  '1954-09-28 20:15:00'" _
            & ",'address': {'streetAddress': '21 2nd Street','city': 'New York','state': 'NY','postalCode': '10021-3100'}" _
            & ",'phoneNumbers': [{'type': 'home','number': '212 555-1234'},{'type': 'office','number': '646 555-4567'}]" _
            & ",'children': ['Q','M','G','T'],'spouse': null}"
        s = Replace(s, "'", """")
        myDict.ImportFromJson(s, OverWrite := True)
        ' (Under)-ordbøkene «Addresse» og «Telefonnummer» (0) og (1) vert importerte som tomme strengar.

## ImportFromPropertyValues

Set inn innhaldet frå ei matrise med PropertyValue-objekta i den gjeldande ordlista. Namna i PropertyValue vert brukte som nøklar i ordlista, medan «Verdiar» inneheld dei tilsvarande verdiane. Returnerer Sann viss vellukka.

### Syntaks:

dict.ImportFromPropertyValues(propertyvalues: obj[0..*], overwrite: bool = False): bool

### Parametrar:

propertyvalue: Ei null-baseret eindimensional matrise som inneheld com.sun.star.beans.PropertyValue-objekt. Denne parameteren kan også vera eit PropertyValue-objekt som ikkje er i ei matrise.

overwrite: Når denne er Sann, kan det finnast oppføringar med det same namnet i ordlista. Verdiane vert i tilfelle overskrivne. Når denne er Usann (standard), vil like verdiar setja opp ein feil. Hugs at ordboksnøklane ikkje skil mellom store og små bokstavar, medan grupper av eigenskapsverdiar i Python gjer det.

### Eksempel:

Eksempla nedanfor lagar først ei matrise med to PropertyValue-objekt og deretter konverterer ho til ei ordliste.

##### I Basic

        Dim vProp As New com.sun.star.beans.PropertyValue
        Dim arrProp : arrProp = Array()
        vProp.Name = "Color"
        vProp.Value = "Blue"
        arrProp = SF_Array.Append(arrProp, vProp)
        vProp.Name = "Date"
        vProp.Value = CDateToUnoDateTime(Now)
        arrProp = SF_Array.Append(arrProp, vProp)
        myDict = CreateScriptService("Dictionary")
        myDict.ImportFromPropertyValues(arrProp, Overwrite := True)
        Dim keys : keys = myDict.Keys
        For Each k In keys
            MsgBox k & " - " & myDict.Item(k)
        Next k

##### I Python

        from scriptforge import CreateScriptService
        from datetime import datetime
        import uno
        bas = CreateScriptService("Basic")
        arrProp = list()
        vProp = uno.createUnoStruct("com.sun.star.beans.PropertyValue")
        vProp.Name = "Color"
        vProp.Value = "Blue"
        arrProp.append(vProp)
        vProp = uno.createUnoStruct("com.sun.star.beans.PropertyValue")
        vProp.Name = "Date"
        vProp.Value = bas.CDateToUnoDateTime(datetime.now())
        arrProp.append(vProp)
        myDict = CreateScriptService("Dictionary")
        myDict.ImportFromPropertyValues(arrProp, overwrite=True)
        for k in myDict.keys():
            bas.MsgBox("{} - {}".format(k, myDict[k]))

## Item

Hentar ei ordbokoppføring som finst frå før basert på nøkkelen. Returnerer verdien av elementet viss vellukka, elles vert Empty returnert.

### Syntaks:

dict.Item(key: str): any

### Parametrar:

nøkkel: Viss han ikkje finst, vert verdien Tom returnert.

### Eksempel:

Det neste eksempelet går gjennom alle nøklane i ordboka fleire gongar og brukar metoden Item til å få tilgang til verdiane.

        Dim myDict as Variant, k as Variant, allKeys as Variant
        myDict = CreateScriptService("Dictionary")
        myDict.Add("key1", 100)
        myDict.Add("key2", 200)
        myDict.Add("key3", 300)
        allKeys = myDict.Keys
        For Each k in allKeys
           MsgBox(myDict.Item(k))
        Next k

## Remove

Fjernar ei ordboksoppføring basert på nøkkelen. Returnerer Sann viss det lukkast.

### Syntaks:

dict.Remove(key: str): bool

### Parametrar:

nøkkel: Må finnast i ordboka, elles vert det generert ein UNKNOWNKEYERROR-feil.

### Eksempel:

        myDict.Add("key1", 100)
        myDict.Add("key2", 200)
        myDict.Add("key3", 300)
        MsgBox(myDict.Count) ' 3
        myDict.Remove("key2")
        MsgBox(myDict.Count) ' 2

## RemoveAll

Fjernar alle oppføringane i ordboka.. Returnerer Sann viss det lukkast.

### Syntaks:

dict.RemoveAll(): bool

### Eksempel:

        myDict.Add("key1", 100)
        myDict.Add("key2", 200)
        myDict.Add("key3", 300)
        MsgBox(myDict.Count) ' 3
        myDict.RemoveAll()
        MsgBox(myDict.Count) ' 0

## ReplaceItem

Fjernar ein elementverdi basert på nøkkelen. Returnerer Sann viss det lukkast.

### Syntaks:

dict.ReplaceItem(key: str, value: any): bool

### Parametrar:

nøkkel: Strengverdi som representerer den verdien som skal bytas ut. Viss nøkkelen ikkje finst i ordboka, vert det generert ein UNKNOWNKEYERROR-feil.

value: Den nye verdien for elementet det vert referert til med Key-parameteren.

### Eksempel:

        myDict.Add("a", 1)
        MsgBox(myDict.Item("a")) ' 1
        myDict.ReplaceItem("a", 100)
        MsgBox(myDict.Item("a")) ' 100

## ReplaceKey

Erstattar ein nøkkel i ordlista med ein ny nøkkel. Elementverdien vert ikkje endra. Returnerer Sann viss det lukkast.

### Syntaks:

dict.ReplaceKey(key: str, value: str): bool

### Parametrar:

nøkkel: Strengverdi som representerer den nøkkelen som skal bytas ut. Viss nøkkelen ikkje finst i ordboka, vert det generert ein UNKNOWNKEYERROR-feil.

verdi: Strengverdi for den nye nøkkelen. Viss den nye nøkkelen finst frå før i ordboka, vert det generert ein DUPLICATEKEYERROR-feil.

### Eksempel:

        myDict.Add("oldKey", 100)
        MsgBox(myDict.Item("oldKey")) ' 100
        myDict.ReplaceKey("oldKey", "newKey")
        MsgBox(myDict.Item("newKey")) ' 100

Alle ScriptForge Basic-rutinane og -identifikatorane som vert innleidde med understrek «_» er reserverte for internt bruk. Dei er ikkje meint brukte i Basic-makroar.

Liknande emne

ScriptForge.Array-teneste

Samlingsobjekt

Støtt oss!